Quick start manual

Procedures and functions 6-15
Parameters
The following example uses untyped parameters in a function called Equal that
compares a specified number of bytes of any two variables.
function Equal(var Source, Dest; Size: Integer): Boolean;
type
TBytes = array[0..MaxInt - 1] of Byte;
var
N: Integer;
begin
N := 0;
while (N < Size) and (TBytes(Dest)[N] = TBytes(Source)[N]) do
Inc(N);
Equal := N = Size;
end;
Given the declarations
type
TVector = array[1..10] of Integer;
TPoint = record
X, Y: Integer;
end;
var
Vec1, Vec2: TVector;
N: Integer;
P: TPoint;
you could make the following calls to Equal:
Equal(Vec1, Vec2, SizeOf(TVector)) // compare Vec1 to Vec2
Equal(Vec1, Vec2, SizeOf(Integer) * N) // compare first N elements of Vec1 and Vec2
Equal(Vec1[1], Vec1[6], SizeOf(Integer) * 5) // compare first 5 to last 5 elements of Vec1
Equal(Vec1[1], P, 4) // compare Vec1[1] to P.X and Vec1[2] to P.Y
String parameters
When you declare routines that take short-string parameters, you cannot include
length specifiers in the parameter declarations. That is, the declaration
procedure Check(S: string[20]); // syntax error
causes a compilation error. But
type TString20 = string[20];
procedure Check(S: TString20);
is valid. The special identifier OpenString can be used to declare routines that take
short-string parameters of varying length:
procedure Check(S: OpenString);
When the {$H–} and {$P+} compiler directives are both in effect, the reserved word
string is equivalent to OpenString in parameter declarations.
Short strings, OpenString, $H, and $P are supported for backward compatibility only.
In new code, you can avoid these considerations by using long strings.