NET/MASTER Network Control Language (NCL) Programmer's Guide

Examples of System-Level NCL Procedures
Developing System-Level NCL Procedures
17–34 106160 Tandem Computers Incorporated
The following EMSPROC NCL procedure filters and displays messages from the
Expand and SNAX/CDF subsystems in distinctive colors; it also intercepts particular
messages from those subsystems and displays those messages in distinctive ways.
zex1712n: PROCEDURE
/* EMSPROC to filter and display messages from various
/* subsystems.
/*
/* SubSystem EXPAND:-
/* Deletes messages where Line Quality is greater than 50%
/* Highlights messages yellow where Line Quality is <= 50%
/* Highlights messages red and reverse for Line Errors
/*
/* SubSystem SNAX/XF:-
/* Deletes LU inactive messages
/* Highlights PU not ready messages red
/* Highlights Line Down messages red and reverse
/*/
WRITE LOG=YES DATA=Starting EMSPROC
DO FOREVER
EMSREAD args
SELECT &1;
/* EXPAND CSS-LINE-QUAL */
WHEN "EXP0033" THEN DO
IF &$ems.spi.tandem.zexp_tkn_line_qual > 50 THEN EMSDEL
ELSE EMSCONT COLOUR=YELLOW INTENS=HIGH
END
/* EXPAND NET-LINE-ERR */
WHEN "EXP0164" THEN DO
EMSCONT COLOUR=RED HLITE=REVERSE
END
/* SNAX/XF LINE DOWN */
WHEN "SX10023" THEN DO
EMSCONT COLOUR=RED HLITE=REVERSE
END
/* SNAX/XF PU-NOT-READY */
WHEN "SX10042" THEN DO
EMSCONT COLOUR=RED
END
/* SNAX/XF LU-INACTV */
WHEN "SX10062" THEN DO
EMSDEL
END
OTHERWISE
EMSCONT
END /*select*/
END /*do*/
END zex1712n